symbolic-diff¶

; Derivative in terms of abstract terms

(define (deriv exp var)
    (cond ((number? exp) 0)
          ((variable? exp) (if (same-variable? exp var) 1 0))
          ((sum? exp) (make-sum (deriv (addend exp) var)
                                (deriv (augend exp) var)))
          ((product? exp)
            (make-sum
                (make-product 
                    (multiplier exp)
                    (deriv (multiplicand exp) var))
                (make-product
                    (deriv (multiplier exp) var)
                    (multiplicand exp))))
          (else
            (error "unknown expression type: DERIV" exp))))

; Representing algebraic expressions
(define (variable? x) (symbol? x))

(define (same-variable? v1 v2)
    (and (variable? v1) (variable? v2) (eq? v1 v2)))

(define (make-sum a1 a2) (list '+ a1 a2))
(define (make-product m1 m2) (list '* m1 m2))

; Sum is a list whose first element is symbol +:
(define (sum? x) (and (pair? x) (eq? (car x) '+)))
(define (addend s) (cadr s))
(define (augend s) (caddr s))

; Product is a list whose first element is symbol *:
(define (product? x) (and (pair? x) (eq? (car x) '*)))
(define (multiplier p) (cadr p))
(define (multiplicand p) (caddr p))

; Basic examples
(deriv '(+ x 3) 'x)
; (+ 1 x)

(deriv '(* x y) 'x)
; (+ (* x 0) (* 1 y))

(deriv '(* (* x y) (+ x 3)) 'x)
; (+ (* (* x y) (+ 1 x)) (* (+ (* x 0) (* 1 y)) (+ x 3)))

; Simplifying expressions
(define (=number? exp num) 
    (and (number? exp) (= exp num)))
(=number? 'a 0) ; false
(=number? 1 1) ; true

(define (make-sum a1 a2) 
    (cond ((=number? a1 0) a2) 
          ((=number? a2 0) a1)
          ((and (number? a1) (number? a2)) (+ a1 a2))
          (else (list '+ a1 a2))))

(make-sum 2 3) ;Value: 5
(make-sum 'x 0) ;Value: x
(make-sum 0 'y) ;Value: y
(make-sum 'x 'y) ;(+ x y)

(define (make-product m1 m2) 
    (cond ((or (=number? m1 0) (=number? m2 0)) 0)
          ((=number? m1 1) m2)
          ((=number? m2 1) m1)
          ((and (number? m1) (number? m2)) (* m1 m2))
          (else (list '* m1 m2))))

(make-product 4 8) ;Value: 32
(make-product 'x 1) ;Value: x
(make-product 1 'x) ;Value: x
(make-product 'y 0) ;Value: 0
(make-product 0 'y) ;Value: 0
(make-product 'x 'y) ;(* x y)

; Testing
(deriv '(+ x 3) 'x)
; 1

(deriv '(* x y) 'x)
; y

(deriv '(* (* x y) (+ x 3)) 'x)
; (+ (* x y) (* y (+ x 3)))